home *** CD-ROM | disk | FTP | other *** search
/ Programming Languages Suite / ProgramD2.iso / Languages / Masm V6.11 / LIB / APPENTRY.AS$ / APPENTRY
Encoding:
Text File  |  1992-09-08  |  3.8 KB  |  110 lines
  1. ;-----------------------------------------------------------------------------;
  2. ; APPENTRY.ASM :Windows Application Startup Routine
  3. ;-----------------------------------------------------------------------------;
  4. ; From Microsoft Windows Software Developers Kit (c) Microsoft
  5. ; Chapter 22: Windows Application Startup
  6. ;-----------------------------------------------------------------------------;
  7. ;
  8. ; To create a Windows application, the WinMain function has to be called
  9. ; by some startup code contained in the executable file. This startup code is 
  10. ; in the APPENTRY.ASM file. Since INVOKE directives depend on the memory model
  11. ; in use, APPENTRY.ASM expects MODEL to be set with the memory model of
  12. ; the application. APPENTRY.OBJ is then created from APPENTRY.ASM.
  13. ;
  14. ; for example:    ml -c -DMODEL=small appentry.asm
  15. ; 
  16. ; In the link line, APPENTRY.OBJ has to be the first file in the chain,
  17. ; because the first 16 bytes of data in the DATA segment are reserved by 
  18. ; Windows. A run file name has to be specified to the linker, otherwise
  19. ; the linker will create an APPENTRY.EXE executable.
  20. ;
  21. ; for example:    link  appentry+winapp,winapp.exe,,libw,winapp
  22. ;
  23. ; For PWB, this amounts to selecting APPENTRY.ASM as the first entry in the
  24. ; list (put APPENTRY.ASM at the Top of List)
  25. ; Since MODEL is required, an IFNDEF handles the case in which it isn't
  26. ; defined, outputting an error and avoiding assembly of the rest.
  27. ;
  28. ;-----------------------------------------------------------------------------;
  29.  
  30.  
  31. IFNDEF MODEL
  32.     .ERR <MODEL hasn't been defined>
  33.     EXTERNDEF  __astart:PROC
  34. ELSE
  35.     .model MODEL, pascal            ; set model to MODEL, language
  36.                     ; to pascal (as required by Windows)
  37.                     ; MODEL should be defined in ML
  38.                     ; command line
  39.  
  40. ; Numeric Equates
  41.  
  42. STACKSLOP = 256                         ; amount of stack slop space required
  43. maxRsrvPtrs = 5                         ; number of Windows reserved pointers
  44.  
  45. ; External/Public definitions
  46.  
  47. EXTERNDEF       rsrvptrs:WORD           ; pointers to Windows reserved pointers
  48. PUBLIC          __astart                ; application startup routine
  49.  
  50. ; Type definitions for functions used. 
  51. ; Faster and more efficient than including 'windows.inc'
  52.  
  53. UINT            TYPEDEF WORD
  54. HINSTANCE       TYPEDEF UINT
  55. HTASK           TYPEDEF UINT
  56. LPSTR           TYPEDEF FAR PTR BYTE
  57.  
  58.  
  59. ; Prototypes for functions used
  60.  
  61. Dos3Call        PROTO FAR PASCAL
  62. InitApp         PROTO FAR PASCAL,       :HTASK
  63. WaitEvent       PROTO FAR PASCAL,       :HINSTANCE
  64. InitTask        PROTO FAR PASCAL
  65. WinMain         PROTO NEAR PASCAL,      :HINSTANCE, :HINSTANCE, :LPSTR, :UINT
  66.  
  67.     .data
  68.  
  69.      DWORD  0                       ; Windows reserved data space.
  70. rsrvptrs WORD   maxRsrvPtrs             ; 16 bytes at the top of the DATA seg.
  71.      WORD   maxRsrvPtrs DUP (0)     ; Do not alter
  72.  
  73. hPrev    WORD    0                      ; space to save WinMain parameters
  74. hInst    WORD    0
  75. lpszCmd  DWORD   0
  76. cmdShow  WORD    0
  77.  
  78.     .code
  79.  
  80. __astart:
  81.     xor bp,bp                       ; zero bp
  82.     push bp
  83.     INVOKE InitTask                 ; Initialize the stack
  84.     or ax,ax
  85.     jz noinit
  86.     add cx,STACKSLOP                ; Add in stack slop space.
  87.     jc noinit                       ; If overflow, return error.
  88.     mov hPrev,si
  89.     mov hInst,di
  90.     mov word ptr lpszCmd,bx
  91.     mov word ptr lpszCmd+2,es
  92.     mov cmdShow,dx
  93.     xor ax,ax                       ; Clear initial event that
  94.     INVOKE WaitEvent, ax            ;   started this task.
  95.     INVOKE InitApp, hInst           ; Initialize the queue.
  96.     or ax,ax
  97.     jz noinit
  98.  
  99.     INVOKE WinMain, hInst,hPrev,lpszCmd,cmdShow
  100. ix:
  101.     mov ah,4Ch
  102.     INVOKE Dos3Call                 ; Exit with return code from app.
  103. noinit:
  104.     mov al,0FFh                     ; Exit with error code.
  105.     jmp short ix
  106.     
  107. ENDIF                                   ; End of IFNDEF MODEL
  108.  
  109.     end __astart                    ; start address
  110.